4 / 74

Insérer du code dans une image

Adresses permettant d'insérer des données dans une page écran sans influencer l'affichage :

&C7D0 à &C7FF = 48 octets
&CFD0 à &CFFF = 48 octets
&D7D0 à &D7FF = 48 octets
&DFD0 à &DFFF = 48 octets
&E7D0 à &E7FF = 48 octets
&EFD0 à &EFFF = 48 octets
&F7D0 à &F7FF = 48 octets
&FFD0 à &FFFF = 48 octets

384 octets utilisables sur une page écran.

A quoi ça peux nous servir me direz-vous et bien voici 2 exemples sur des images en MODE 0.

Exemple 1 : Palette de couleur dans l'image (On retrouve cette technique sur quelque jeu édité par TITUS Software)

Etape 1 : Incorporer nos couleurs dans une image et la sauvegarder

10 MODE 0
20 LOAD"monimage.scr",&C000 'charger l'image a l'écran &C000 ou 49152
30 FOR I=0 to 15:READ A:POKE &FFD0+I,A:NEXT 'écrire les couleurs dans l'image a partir de &FFD0
40 SAVE"monimage.scr",b,&C000,&4000 'sauver l'image en mode binaire, adresse de début, longeur
50 DATA 1,2,3,4,5,6,7,8,9,10,11,12,13,14,15 'les 16 couleurs

Etape 2 : Voir le résultat de notre travail

10 MODE 0:BORDER 0
20 FOR I=0 to 15:INK I,0:NEXT 'toutes les encres en noir
30 LOAD"monimage.scr",&C000 'charger l'image a l'écran &C000 ou 49152
40 FOR I=0 to 15:INK I,PEEK(&FFD0+I):NEXT 'lire les couleurs qui sont dans l'image
50 PRINT CHR$(7):CALL &BB06 'faire un BEEP, et attendre l'appui sur une touche

Exemple 2 : Palette de couleur dans l'image + routine en assembleur pour charger les couleurs

Etape 1 : Incorporer nos couleurs dans une image ainsi qu'une routine en assembleur et la sauvegarder

10 MODE 0
20 LOAD"monimage.scr",&C000
30 FOR I=&FFD0 to &FFFB:READ A$:POKE I,VAL("&"+A$):NEXT
40 SAVE"monimage.scr",b,&C000,&4000
50 DATA 01,00,00 'couleur pour la bordure (00,00) ici noir si 2 couleurs différente alors ça clignote
60 DATA CD,38,BC
70 DATA 21,ED,FF 'adresse de début de la palette &FFED
80 DATA AF,F5,E5,46,48,CD,32,BC,E1,23,F1,3C,FE
90 DATA 10 '&10 = 16 couleurs, &4 = 4 couleurs, &2 = 2 couleurs, suivant le mode écran choisit
100 DATA 20,F1,CD,06,BB,C9
110 DATA 1,2,3,4,5,6,7,8,9,10,11,12,13,14,15 'les 16 couleurs

Etape 2 : Voir le résultat de notre travail

10 MODE 0
20 FOR I=0 to 15:INK I,0:NEXT 'toutes les encres en noir
30 LOAD"monimage.scr",&C000 'charger l'image a l'écran &C000 ou 49152
40 CALL &FFD0 'lire les couleurs qui sont dans l'image

Par Kukulcan